Knot physics, deriving the fine structure constant

This notebook accompanies the paper “Knot physics: deriving the fine structure constant”
Both are available at www.knotphysics.net
author:           Cliff Ellgen
author email:  cellgen@gmail.com

We estimate the fine structure constant α by calculating the spin angular momentum S as a function of charge q.  Then α-1 = (8ℼS)/((q^2))

begin variable definition

radius is the S^1 radius of the particle.  Can be any positive value.  
charge is the charge of the particle.  Can be any non-zero value.

radius=1;

charge=1;

end variable definition

begin function definition





all functions take toroidal coordinate inputs

rco gives the r coordinate (needed to calculate angular momentum = r x p)
dVtor gives the measure dV in toroidal coordinates.  The factor of 2pi is because the integration will be done in the tau, sigma plane and the 2pi factor includes integration over the phi angle.

rco[tau_,sigma_,phi_]:=radius*Sinh[tau]*(Cosh[tau]-Cos[sigma])^(-1)*Cos[phi];

dVtor[tau_,sigma_]:=2*Pi*Abs[(radius^3*Sinh[tau])/(Cosh[tau]-Cos[sigma])^3];

begin calculation of rho  

harmonic gives the harmonic function whose source is the circle of radius "radius" in the z=0 plane.
rho scales harmonic so that rho scales like 1/d as it approaches the source.

harmonic[tau_,sigma_]:=(Cosh[tau]-Cos[sigma])^(1/2)*LegendreP[-1/2,0,Cosh[tau]];

rho[tau_,sigma_]:=E^((Pi*2^(-1/2))*harmonic[tau, sigma]);

end calculation of rho

Divergence functions 

DivField has divergence at the source but has zero divergence and zero curl everywhere else.  
ScaledDivField scales DivField so the divergence matches the charge.

DivField[tau_,sigma_]:={-(1/radius)*Sinh[tau]*(Cosh[tau]-Cos[sigma])^(1/2)*((1/2)*LegendreP[-1/2,0,Cosh[tau]]+(Cosh[tau]-Cos[sigma])*D[LegendreP[-1/2,0,x],x]/.x->Cosh[tau]),-(1/radius)*(Cosh[tau]-Cos[sigma])^(1/2)*((1/2)*Sin[sigma]*LegendreP[-1/2,0,Cosh[tau]]),0};

ScaledDivField[tau_,sigma_]:=charge*(1/radius)*(4*Pi*2^(1/2))^(-1)*DivField[tau, sigma];

end divergence functions

Curl functions

StokesCurrent assists with the calculation of CurlField.
CurlField has curl at the source but has zero divergence and zero curl everywhere else. 
ScaledCurlField scales CurlField so the curl matches the current (current=charge).

StokesCurrent[tau_,sigma_]:=I*(Cosh[tau]-Cos[sigma])^(-1/2)*Sinh[tau]*LegendreP[-1/2,1, Cosh[tau]];

CurlField[tau_, sigma_]:={-(Cosh[tau]-Cos[sigma])^2*(radius^2*Sinh[tau])^(-1)*D[StokesCurrent[tau, y],y]/.y->sigma,(Cosh[tau]-Cos[sigma])^2*(radius^2*Sinh[tau])^(-1)*D[StokesCurrent[y, sigma],y]/.y->tau,0};

ScaledCurlField[tau_,sigma_]:=charge*2^(-1/2)*Re[CurlField[tau, sigma]];

end curl functions

end function definitions

begin AlphaInverse computation

The spin angular momentum is the integral of radius*(momentum in phi direction) on flat space, the momentum is constant in phi, therefore   
S = ∫ r * momentum * (2*Pi*r) dr dz
In toroidal coordinates this is 
S = ∫ rco * momentum * dVtor dtau dsigma

from the paper "Knot physics, deriving the fine structure constant" we have
momentum = (1+20*Pi^2) * (1/rho^2) * Cross[ScaledCurlField,ScaledDivField]

Then AlphaInverse = 4*Pi*hbar/q^2 = 4*Pi*2*S/q^2 = (1/q^2)*(8*Pi)*S

S=NIntegrate[rco[tau,sigma,0]*(1+20*Pi^2)*(1/rho[tau,sigma]^2)*Norm[Cross[{ScaledCurlField[tau,sigma][[1]],ScaledCurlField[tau,sigma][[2]],0},{ScaledDivField[tau,sigma][[1]],ScaledDivField[tau,sigma][[2]],0}]]*dVtor[tau,sigma],{tau,0,Infinity},{sigma,-Pi,Pi}]

Fine structure constant calculation and error

Needs["PhysicalConstants`"];  (* import physical constants *)

1/FineStructureConstant  (*  actual value *)

AlphaInverseCalc=(1/charge^2)*(8*Pi)*S  (*calculated value*)

AlphaInverseError=AlphaInverseCalc-(1/FineStructureConstant) (*total error*)

PercentError=100*AlphaInverseError/(1/FineStructureConstant)"%"  (*percent error *)